twKatPersons. Интерфейс предоставления данных сторонним модулям

Файл: Example\Src\VIP\Staff\twKatPersons.vip

Издание 01.2007. Добавлены директивы документирования.

//******************************************************************************
//													(c) корпорация Галактика
// Демопроект 1.0 - Управление персоналом
// Реализация табличного объекта персональных данных
//******************************************************************************

#include IKatPersons.vih

#component "C_STAFF"

//******************************************************************************
#doc
 Реализация табличного объекта персональных данных.
#end

interface twKatPersons;

create view

as select
  KatPersons.*, KatPosts.Name, KatDeps.Name

from
  KatPersons, KatPosts, KatDeps

where
((
		KatPersons.cDepartment == KatDeps.NREC
	and KatPersons.cPost	 == KatPosts.NREC
))
;

//------------------------------------------------------------------------------

property IKatPersons.NRec : comp absolute KatPersons.NRec read;

property IKatPersons.FIO : string[35]
  read KatPersons.LastName + ' ' + SubStr(KatPersons.FirstName, 1, 1) + '.'
	 + SubStr(KatPersons.MiddleName, 1, 1) + '.';

property IKatPersons.Salary : double
  read (KatPersons.Taxrate + KatPersons.Raise)/21;

property IKatPersons.Department : string[20] absolute KatDeps.Name read;

property IKatPersons.Post : string[20] absolute KatPosts.Name read;

//------------------------------------------------------------------------------

function IModify.doInsert : word;
{
  Result := insert current KatPersons;
}

//------------------------------------------------------------------------------

function IModify.doUpdate : word;
{
  Result := update current KatPersons;
}

//------------------------------------------------------------------------------

function IModify.doDelete : word;
{
  Result := delete current KatPersons;
}

//------------------------------------------------------------------------------

implementation IModify.doFlush abstract;

index IKatPersons.KatPersons0 auto;

end.